Tutorial for the &GAP; Character Table Library

This chapter gives an overview of the basic functionality provided by the &GAP; Character Table Library. The main concepts and interface functions are presented in the sections and , Section shows a few small examples.

Concepts used in the &GAP; Character Table Library

The main idea behind working with the &GAP; Character Table Library is to deal with character tables of groups but without having access to these groups. This situation occurs for example if one extracts information from the printed &ATLAS; of Finite Groups ().

This restriction means first of all that we need a way to access the character tables, see Section for that. Once we have such a character table, we can compute all those data about the underlying group G, say, that are determined by the character table. Chapter lists such attributes and properties. For example, it can be computed from the character table of G whether G is solvable or not.

Questions that cannot be answered using only the character table of G can perhaps be treated using additional information. For example, the structure of subgroups of G is in general not determined by the character table of G, but the character table may yield partial information. Two examples can be found in the sections and .

In the character table context, the role of homomorphisms between two groups is taken by class fusions. Monomorphisms correspond to subgroup fusions, epimorphisms correspond to factor fusions. Given two character tables of a group G and a subgroup H of G, one can in general compute only candidates for the class fusion of H into G, for example using . Note that G may contain several nonconjugate subgroups isomorphic with H, which may have different class fusions.

One can often reduce a question about a group G to a question about its maximal subgroups. In the character table context, it is often sufficient to know the character table of G, the character tables of its maximal subgroups, and their class fusions into G. We are in this situation if the attribute is set in the character table of G.

Summary:
The character theoretic approach that is supported by the &GAP; Character Table Library, that is, an approach without explicitly using the underlying groups, has the advantages that it can be used to answer many questions, and that these computations are usually cheap, compared to computations with groups. Disadvantages are that this approach is not always successful, and that answers are often nonconstructive in the sense that one can show the existence of something without getting one's hands on it.

Accessing a Character Table from the Library

As stated in Section , we must define how character tables from the &GAP; Character Table Library can be accessed.

Accessing a Character Table via a name

The most common way to access a character table from the &GAP; Character Table Library is to call with argument a string that is an admissible name for the character table. Typical admissible names are similar to the group names used in the &ATLAS; of Finite Groups . One of these names is the value of the character table, this name is used by &GAP; when it prints library character tables.

For example, an admissible name for the character table of an almost simple group is the &ATLAS; name, such as A5, M11, or L2(11).2.

Other names may be admissible, for example S6 is admissible for the symmetric group on six points, which is called A_6.2_1 in the &ATLAS;.

gap> CharacterTable( "J1" ); CharacterTable( "J1" ) gap> CharacterTable( "L2(11)" ); CharacterTable( "L2(11)" ) gap> CharacterTable( "S5" ); CharacterTable( "A5.2" )
Accessing a Character Table via properties

If one does not know an admissible name of the character table of a group one is interested in, or if one does not know whether ths character table is available at all, one can use to compute a list of identifiers of all available character tables with given properties. Analogously, can be used to compute one such identifier.

gap> AllCharacterTableNames( Size, 120 ); [ "2.A5", "2.A6M2", "2xA5", "A5.2", "A6.2_1M3", "D120", "L2(25)M3" ] gap> OneCharacterTableName( NrConjugacyClasses, n -> n <= 4 ); "S3"

For certain filters, such as and , the computations are fast because the values for all library tables are precomputed. See for an overview of these filters.

The function provides an interactive overview of available character tables, which allows one for example to search also for substrings in identifiers of character tables. This function is available only if the `Browse` package has been loaded.

Accessing a Character Table via a Table of Marks

Let G be a group whose table of marks is available via the `TomLib` package (see for how to access tables of marks from this library) then the &GAP; Character Table Library contains the character table of G, and one can access this table by using the table of marks as an argument of .

gap> tom:= TableOfMarks( "M11" ); TableOfMarks( "M11" ) gap> t:= CharacterTable( tom ); CharacterTable( "M11" )
Accessing a Character Table relative to another Character Table

If one has already a character table from the &GAP; Character Table Library that belongs to the group G, say, then names of related tables can be found as follows.

The value of the attribute , if known, is the list of identifiers of the character tables of all classes of maximal subgroups of G.

gap> t:= CharacterTable( "M11" ); CharacterTable( "M11" ) gap> HasMaxes( t ); true gap> Maxes( t ); [ "A6.2_3", "L2(11)", "3^2:Q8.2", "A5.2", "2.S4" ]

If the value of the character table with identifier id, say, is known then the character table of the groups in the i-th class of maximal subgroups can be accessed via the relative name id M i.

gap> CharacterTable( "M11M2" ); CharacterTable( "L2(11)" )

The value of the attribute is the list of identifiers of those character tables which store class fusions to G. So these character tables belong to subgroups of G and groups that have G as a factor group.

gap> NamesOfFusionSources( t ); [ "A5.2", "A6.2_3", "P48/G1/L1/V1/ext2", "P48/G1/L1/V2/ext2", "L2(11)", "2.S4", "3^5:M11", "3^6.M11", "3^2:Q8.2", "M11N2", "5:4", "11:5" ]

The value of the attribute is the list of records whose name components are the identifiers of those character tables to which class fusions are stored. So these character tables belong to overgroups and factor groups of G.

gap> List( ComputedClassFusions( t ), r -> r.name ); [ "A11", "M12", "M23", "HS", "McL", "ON", "3^5:M11", "B" ]
Different character tables for the same group

The &GAP; Character Table Library may contain several different character tables of a given group, in the sense that the rows and columns are sorted differently.

For example, the &ATLAS; table of the alternating group A_5 is available, and since A_5 is isomorphic with the groups PSL(2, 4) and PSL(2, 5), two more character tables of A_5 can be constructed in a natural way. The three tables are of course permutation isomorphic. The first two are sorted in the same way, but the rows and columns of the third one are sorted differently.

gap> t1:= CharacterTable( "A5" );; gap> t2:= CharacterTable( "PSL", 2, 4 );; gap> t3:= CharacterTable( "PSL", 2, 5 );; gap> TransformingPermutationsCharacterTables( t1, t2 ); rec( columns := (), group := Group([ (4,5) ]), rows := () ) gap> TransformingPermutationsCharacterTables( t1, t3 ); rec( columns := (2,4)(3,5), group := Group([ (2,3) ]), rows := (2,5,3,4) )

Another situation where several character tables for the same group are available is that a group contains several classes of isomorphic maximal subgroups such that the class fusions are different.

For example, the Mathieu group M_{12} contains two classes of maximal subgroups of index 12, which are isomorphic with M_{11}.

gap> t:= CharacterTable( "M12" ); CharacterTable( "M12" ) gap> mx:= Maxes( t ); [ "M11", "M12M2", "A6.2^2", "M12M4", "L2(11)", "3^2.2.S4", "M12M7", "2xS5", "M8.S4", "4^2:D12", "A4xS3" ] gap> s1:= CharacterTable( mx[1] ); CharacterTable( "M11" ) gap> s2:= CharacterTable( mx[2] ); CharacterTable( "M12M2" )

The class fusions into M_{12} are stored on the library tables of the maximal subgroups. The groups in the first class of M_{11} type subgroups contain elements in the classes 4B, 6B, and 8B of M_{12}, and the groups in the second class contain elements in the classes 4A, 6A, and 8A. Note that according to the &ATLAS; (see ), the permutation characters of the action of M_{12} on the cosets of M_{11} type subgroups from the two classes of maximal subgroups are 1a + 11a and 1a + 11b, respectively.

gap> GetFusionMap( s1, t ); [ 1, 3, 4, 7, 8, 10, 12, 12, 15, 14 ] gap> GetFusionMap( s2, t ); [ 1, 3, 4, 6, 8, 10, 11, 11, 14, 15 ] gap> Display( t ); M12

2 6 4 6 1 2 5 5 1 2 1 3 3 1 . . 3 3 1 1 3 2 . . . 1 1 . . . . . 5 1 1 . . . . . 1 . . . . 1 . . 11 1 . . . . . . . . . . . . 1 1

1a 2a 2b 3a 3b 4a 4b 5a 6a 6b 8a 8b 10a 11a 11b 2P 1a 1a 1a 3a 3b 2b 2b 5a 3b 3a 4a 4b 5a 11b 11a 3P 1a 2a 2b 1a 1a 4a 4b 5a 2a 2b 8a 8b 10a 11a 11b 5P 1a 2a 2b 3a 3b 4a 4b 1a 6a 6b 8a 8b 2a 11a 11b 11P 1a 2a 2b 3a 3b 4a 4b 5a 6a 6b 8a 8b 10a 1a 1a

X.1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 X.2 11 -1 3 2 -1 -1 3 1 -1 . -1 1 -1 . . X.3 11 -1 3 2 -1 3 -1 1 -1 . 1 -1 -1 . . X.4 16 4 . -2 1 . . 1 1 . . . -1 A /A X.5 16 4 . -2 1 . . 1 1 . . . -1 /A A X.6 45 5 -3 . 3 1 1 . -1 . -1 -1 . 1 1 X.7 54 6 6 . . 2 2 -1 . . . . 1 -1 -1 X.8 55 -5 7 1 1 -1 -1 . 1 1 -1 -1 . . . X.9 55 -5 -1 1 1 3 -1 . 1 -1 -1 1 . . . X.10 55 -5 -1 1 1 -1 3 . 1 -1 1 -1 . . . X.11 66 6 2 3 . -2 -2 1 . -1 . . 1 . . X.12 99 -1 3 . 3 -1 -1 -1 -1 . 1 1 -1 . . X.13 120 . -8 3 . . . . . 1 . . . -1 -1 X.14 144 4 . . -3 . . -1 1 . . . -1 1 1 X.15 176 -4 . -4 -1 . . 1 -1 . . . 1 . .

A = E(11)+E(11)^3+E(11)^4+E(11)^5+E(11)^9 = (-1+Sqrt(-11))/2 = b11

Permutation equivalent library tables are related to each other. In the above example, the table s2 is a duplicate of s1, and there are functions for making the relations explicit.

gap> IsDuplicateTable( s2 ); true gap> IdentifierOfMainTable( s2 ); "M11" gap> IdentifiersOfDuplicateTables( s1 ); [ "HSM9", "M12M2", "ONM11" ]

See Section for details about duplicate character tables.

Examples of Using the &GAP; Character Table Library

The sections , , and show how the function can be used to search for character tables with certain properties. The &GAP; Character Table Library serves as a tool for finding and checking conjectures in these examples.

In Section , a question about a subgroup of the sporadic simple Fischer group G = Fi_{23} is answered using only character tables from the &GAP; Character Table Library.

More examples can be found in , , , , .

Example: Ambivalent Simple Groups

A group G is called ambivalent if each element in G is G-conjugate to its inverse. Equivalently, G is ambivalent if all its characters are real-valued. We are interested in simple ambivalent groups. Since ambivalence is invariant under permutation equivalence, we may omit duplicate character tables.

gap> isambivalent:= tbl -> PowerMap( tbl, -1 ) > = [ 1 .. NrConjugacyClasses( tbl ) ];; gap> AllCharacterTableNames( IsSimple, true, IsDuplicateTable, false, > isambivalent, true ); [ "3D4(2)", "A10", "A14", "A5", "A6", "J1", "J2", "L2(101)", "L2(109)", "L2(113)", "L2(121)", "L2(125)", "L2(13)", "L2(16)", "L2(17)", "L2(25)", "L2(29)", "L2(32)", "L2(37)", "L2(41)", "L2(49)", "L2(53)", "L2(61)", "L2(64)", "L2(73)", "L2(8)", "L2(81)", "L2(89)", "L2(97)", "O7(5)", "O8+(2)", "O8+(3)", "O8+(7)", "O8-(2)", "O8-(3)", "O9(3)", "S10(2)", "S12(2)", "S4(4)", "S4(5)", "S4(8)", "S4(9)", "S6(2)", "S6(4)", "S6(5)", "S8(2)" ]
Example: Simple p-pure Groups

A group G is called p-pure for a prime integer p that divides |G| if the centralizer orders of nonidentity p-elements in G are p-powers. Equivalently, G is p-pure if p divides |G| and each element in G of order divisible by p is a p-element. (This property was studied by L. Héthelyi in 2002.)

We are interested in small nonabelian simple p-pure groups.

gap> isppure:= function( p ) > return tbl -> Size( tbl ) mod p = 0 and > ForAll( OrdersClassRepresentatives( tbl ), > n -> n mod p <> 0 or IsPrimePowerInt( n ) ); > end;; gap> for i in [ 2, 3, 5, 7, 11, 13 ] do > Print( i, "\n", > AllCharacterTableNames( IsSimple, true, IsAbelian, false, > IsDuplicateTable, false, isppure( i ), true ), > "\n" ); > od; 2 [ "A5", "A6", "L2(16)", "L2(17)", "L2(31)", "L2(32)", "L2(64)", "L2(8)", "L3(2)", "L3(4)", "Sz(32)", "Sz(8)" ] 3 [ "A5", "A6", "L2(17)", "L2(19)", "L2(27)", "L2(53)", "L2(8)", "L2(81)", "L3(2)", "L3(4)" ] 5 [ "A5", "A6", "A7", "L2(11)", "L2(125)", "L2(25)", "L2(49)", "L3(4)", "M11", "M22", "S4(7)", "Sz(32)", "Sz(8)", "U4(2)", "U4(3)" ] 7 [ "A7", "A8", "A9", "G2(3)", "HS", "J1", "J2", "L2(13)", "L2(49)", "L2(8)", "L2(97)", "L3(2)", "L3(4)", "M22", "O8+(2)", "S6(2)", "Sz(8)", "U3(3)", "U3(5)", "U4(3)", "U6(2)" ] 11 [ "A11", "A12", "A13", "Co2", "HS", "J1", "L2(11)", "L2(121)", "L2(23)", "L5(3)", "M11", "M12", "M22", "M23", "M24", "McL", "ON", "Suz", "U5(2)", "U6(2)" ] 13 [ "2E6(2)", "2F4(2)'", "3D4(2)", "A13", "A14", "A15", "F4(2)", "Fi22", "G2(3)", "G2(4)", "L2(13)", "L2(25)", "L2(27)", "L3(3)", "L4(3)", "O7(3)", "O8+(3)", "S4(5)", "S6(3)", "Suz", "Sz(8)", "U3(4)" ]

Looking at these examples, we may observe that the alternating group A_n of degree n is 2-pure iff n \in \{ 4, 5, 6 \}, 3-pure iff n \in \{ 3, 4, 5, 6 \}, and p-pure, for p \geq 5, iff n \in \{ p, p+1, p+2 \}.

Also, the Suzuki groups Sz(q) are 2-pure since the centralizers of nonidentity 2-elements are contained in Sylow 2-subgroups.

From the inspection of the generic character table(s) of PSL(2, q), we see that PSL(2, p^d) is p-pure Additionally, exactly the following cases of l-purity occur, for a prime l.

q
is even and q-1 or q+1 is a power of l.
For q \equiv 1 \pmod{4}, (q+1)/2 is a power of l or q-1 is a power of l = 2.
For q \equiv 3 \pmod{4}, (q-1)/2 is a power of l or q+1 is a power of l = 2.
Example: Simple Groups with only one p-Block

Are there nonabelian simple groups with only one p-block, for some prime p?

gap> fun:= function( tbl ) > local result, p, bl; > > result:= false; > for p in Set( Factors( Size( tbl ) ) ) do > bl:= PrimeBlocks( tbl, p ); > if Length( bl.defect ) = 1 then > result:= true; > Print( "only one block: ", Identifier( tbl ), ", p = ", p, "\n" ); > fi; > od; > > return result; > end;; gap> AllCharacterTableNames( IsSimple, true, IsAbelian, false, > IsDuplicateTable, false, fun, true ); only one block: M22, p = 2 only one block: M24, p = 2 [ "M22", "M24" ]

We see that the sporadic simple groups M_{22} and M_{24} have only one 2-block.

Example:The Sylow 3 subgroup of 3.O'N

We want to determine the structure of the Sylow 3-subgroups of the triple cover G = 3.O'N of the sporadic simple O'Nan group O'N. The Sylow 3-subgroup of O'N is an elementary abelian group of order 3^4, since the Sylow 3 normalizer in O'N has the structure 3^4:2^{1+4}D_{10} (see ).

gap> CharacterTable( "ONN3" ); CharacterTable( "3^4:2^(1+4)D10" )

Let P be a Sylow 3-subgroup of G. Then P is not abelian, since the centralizer order of any preimage of an element of order three in the simple factor group of G is not divisible by 3^5. Moreover, the exponent of P is three.

gap> 3t:= CharacterTable( "3.ON" );; gap> orders:= OrdersClassRepresentatives( 3t );; gap> ord3:= PositionsProperty( orders, x -> x = 3 ); [ 2, 3, 7 ] gap> sizes:= SizesCentralizers( 3t ){ ord3 }; [ 1382446517760, 1382446517760, 3240 ] gap> Size( 3t ); 1382446517760 gap> Collected( Factors( sizes[3] ) ); [ [ 2, 3 ], [ 3, 4 ], [ 5, 1 ] ] gap> 9 in orders; false

So both the centre and the Frattini subgroup of P are equal to the centre of G, hence P is an extraspecial group 3^{1+4}_+.

Example: Primitive Permutation Characters of 2.A_6

It is often interesting to compute the primitive permutation characters of a group G, that is, the characters of the permutation actions of G on the cosets of its maximal subgroups. These characters can be computed for example when the character tables of G, the character tables of its maximal subgroups, and the class fusions from these character tables into the table of G are known.

gap> tbl:= CharacterTable( "2.A6" );; gap> HasMaxes( tbl ); true gap> maxes:= Maxes( tbl ); [ "2.A5", "2.A6M2", "3^2:8", "2.Symm(4)", "2.A6M5" ] gap> mx:= List( maxes, CharacterTable );; gap> prim1:= List( mx, s -> TrivialCharacter( s )^tbl );; gap> Display( tbl, > rec( chars:= prim1, centralizers:= false, powermap:= false ) ); 2.A6

1a 2a 4a 3a 6a 3b 6b 8a 8b 5a 10a 5b 10b

Y.1 6 6 2 3 3 . . . . 1 1 1 1 Y.2 6 6 2 . . 3 3 . . 1 1 1 1 Y.3 10 10 2 1 1 1 1 2 2 . . . . Y.4 15 15 3 3 3 . . 1 1 . . . . Y.5 15 15 3 . . 3 3 1 1 . . . .

These permutation characters are the ones listed in .

gap> PermCharInfo( tbl, prim1 ).ATLAS; [ "1a+5a", "1a+5b", "1a+9a", "1a+5a+9a", "1a+5b+9a" ]

Alternatively, one can compute the primitive permutation characters from the table of marks if this table and the fusion into it are known.

gap> tom:= TableOfMarks( tbl ); TableOfMarks( "2.A6" ) gap> allperm:= PermCharsTom( tbl, tom );; gap> prim2:= allperm{ MaximalSubgroupsTom( tom )[1] };; gap> Display( tbl, > rec( chars:= prim2, centralizers:= false, powermap:= false ) ); 2.A6

1a 2a 4a 3a 6a 3b 6b 8a 8b 5a 10a 5b 10b

Y.1 6 6 2 3 3 . . . . 1 1 1 1 Y.2 6 6 2 . . 3 3 . . 1 1 1 1 Y.3 10 10 2 1 1 1 1 2 2 . . . . Y.4 15 15 3 . . 3 3 1 1 . . . . Y.5 15 15 3 3 3 . . 1 1 . . . .

We see that the two approaches yield the same permutation characters, but the two lists are sorted in a different way. The latter is due to the fact that the rows of the table of marks are ordered in a way that is not compatible with the ordering of maximal subgroups for the character table. Moreover, there is no way to choose the fusion from the character table to the table of marks in such a way that the two lists of permutation characters would become equal. The component perm in the record of the character table describes the incompatibility.

gap> FusionToTom( tbl ); rec( map := [ 1, 2, 5, 4, 8, 3, 7, 11, 11, 6, 13, 6, 13 ], name := "2.A6", perm := (4,5), text := "fusion map is unique up to table autom." )
Example: A Permutation Character of Fi_{23}

Let x be a 3B element in the sporadic simple Fischer group G = Fi_{23}. The normalizer M of x in G is a maximal subgroup of the type 3^{{1+8}}_+.2^{{1+6}}_-.3^{{1+2}}_+.2S_4. We are interested in the distribution of the elements of the normal subgroup N of the type 3^{{1+8}}_+ in M to the conjugacy classes of G.

This information can be computed from the permutation character \pi = 1_N^G, so we try to compute this permutation character. We have \pi = (1_N^M)^G, and 1_N^M can be computed as the inflation of the regular character of the factor group M/N to M. Note that the character tables of G and M are available, as well as the class fusion of M in G, and that N is the largest normal 3-subgroup of M.

gap> t:= CharacterTable( "Fi23" ); CharacterTable( "Fi23" ) gap> mx:= Maxes( t ); [ "2.Fi22", "O8+(3).3.2", "2^2.U6(2).2", "S8(2)", "S3xO7(3)", "2..11.m23", "3^(1+8).2^(1+6).3^(1+2).2S4", "Fi23M8", "A12.2", "(2^2x2^(1+8)).(3xU4(2)).2", "2^(6+8):(A7xS3)", "S4xS6(2)", "S4(4).4", "L2(23)" ] gap> m:= CharacterTable( mx[7] ); CharacterTable( "3^(1+8).2^(1+6).3^(1+2).2S4" ) gap> n:= ClassPositionsOfPCore( m, 3 ); [ 1 .. 6 ] gap> f:= m / n; CharacterTable( "3^(1+8).2^(1+6).3^(1+2).2S4/[ 1, 2, 3, 4, 5, 6 ]" ) gap> reg:= 0 * [ 1 .. NrConjugacyClasses( f ) ];; gap> reg[1]:= Size( f );; gap> infl:= reg{ GetFusionMap( m, f ) }; [ 165888, 165888, 165888, 165888, 165888, 165888, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ] gap> ind:= Induced( m, t, [ infl ] ); [ ClassFunction( CharacterTable( "Fi23" ), [ 207766624665600, 0, 0, 0, 603832320, 127567872, 6635520, 663552, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ] ) ] gap> PermCharInfo( t, ind ).contained; [ [ 1, 0, 0, 0, 864, 1538, 3456, 13824, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ] ] gap> PositionsProperty( OrdersClassRepresentatives( t ), x -> x = 3 ); [ 5, 6, 7, 8 ]

Thus N contains 864 elements in the class 3A, 1\,538 elements in the class 3B, and so on.