#autoload

# Usage: _rpm_packages expl... avail|installed|uninstalled

_rpm_packages_update_avail () {
  if ( [[ ${+_rpm_packages_cache_avail} -eq 0 ]] ||
      _cache_invalid RPMS_avail ) && ! _retrieve_cache RPMS_avail;
  then
    _rpm_packages_cache_avail=(
      ${(z)${$(apt-cache --no-generate pkgnames):#*(.|\/|\()*}}
    )

    _store_cache RPMS_avail _rpm_packages_cache_avail
  fi
  cachevar=_rpm_packages_cache_avail
}

_rpm_packages_update_installed () {
  if ( [[ ${+_rpm_packages_cache_installed} -eq 0 ]] ||
      _cache_invalid RPMS_installed ) && ! _retrieve_cache RPMS_installed;
  then
    _rpm_packages_cache_installed=(
      ${(z)$(rpm -qa --qf '%{NAME}')}
    )
    _store_cache RPMS_installed _rpm_packages_cache_installed
  fi
  cachevar=_rpm_packages_cache_installed
}

_rpm_packages_update_uninstalled () {
  _rpm_packages_update_avail
  _rpm_packages_update_installed
  if (( ! $+_rpm_packages_cache_uninstalled )); then
    _rpm_packages_cache_uninstalled=(
      ${_rpm_packages_cache_avail:#${(j:|:)~${_rpm_packages_cache_installed:q}}}
    )
  fi
  cachevar=_rpm_packages_cache_uninstalled
}

_rpm_packages () {
  local command="$argv[$#]" expl cachevar pkgset update_policy

  zstyle -s ":completion:*:*:$service:*" cache-policy update_policy
  if [[ -z "$update_policy" ]]; then
    zstyle ":completion:*:*:$service:*" cache-policy _rpms_caching_policy
  fi

  [[ "$command" = (installed|uninstalled|avail) ]] || {
    _message "_rpm_packages:unknown command: $command"
    return
  }

  zstyle -s ":completion:${curcontext}:" packageset pkgset

  [[ "$pkgset" = (installed|uninstalled|avail|available) ]] || {
    pkgset="$command"
  }

  [[ "$pkgset" = "available" ]] && pkgset="avail"

  expl=("${(@)argv[1,-2]}")

  _rpm_packages_update_$pkgset

  _tags packages && compadd "$expl[@]" - "${(@P)cachevar}"
}

_rpms_caching_policy () {
  # rebuild if cache is more than a week old
  oldp=( "$1"(mw+1) )
  (( $#oldp )) && return 0

  pkg_indices=( /var/lib/rpm/{packages.rpm,Packages}(N) )
  for pkg_index in $pkg_indices; do
    [[ "$pkg_index" -nt "$1" ]] && return 0
  done
}



_rpm_packages "$@"
